質問用スレッド

1：shikemokuMK:

2012/08/31 (Fri) 17:40:08

ティラノスクリプトに関するわからない事がありましたら、お気軽にどうぞ

614：シケモクMK :

2014/05/12 (Mon) 12:21:49

>>614
すず さん
こんにちは。

１点目について、色々方法があるのですが
キャラクター名の切り替え処理をマクロ化して
その状態に付随してメッセージレイヤの表示を切り替えるとうまくいきそうです。　

;===以下、サンプルコード

;キャラクター名の表示を切り替える
[macro name="say"]

@chara_ptext name=%name|""

[iscript]
//現在のキャラクタ名を取得
tf.chara_name = $("."+this.kag.stat.chara_ptext).html();
[endscript]

;キャラクター名が設定されていない時はmessage1を表示
[if exp='tf.chara_name ===""']
@layopt layer=message1 visible=true
@layopt layer=message0 visible=false
@current layer="message1"
[else]
@layopt layer=message0 visible=true
@layopt layer=message1 visible=false
@current layer="message0"
[endif]

[endmacro]


;上記のマクロを使った例

メッセージレイヤテスト[p]

@say name="まりこ"
ここはmessage0に表示される[p]

@say name=""
名前が指定されていないのでmessage1に表示される[p]

@say name="ゆうこ"
再度名前が設定されたので、message0に表示[p]

このようにに指定しておくと、自動的にレイヤが切り替わるので
毎回状況ごとに、0,1を切り替えるよりは負担は下がるかなと思います。

２点目
ptextタグを使うのが一番簡単かと思います。
レイヤは、文字の後ろに背景などを指定したい場合は分けたほうが良さそうですね。

[layopt layer=0 visible=true]
[ptext layer=0 name="time1" x=200 y=200 text="変更前の文字" ]

[iscript]
$(".time1").html("変更後の文字");
[endscript]

例えば、[ptext] を変更するなら上記のようにname属性を指定しておくと
スクリプトから、　$(".変数名") という形でアクセスできるので値を変更できます。

このようにすれば、メッセージレイヤに関係なくステータス画面みたいなものを作れるかと思います。
お試し頂けると幸いです。

このトピックはレス満タンなので返信できません。